People are throwing so much away they really do not have too. I see monitors, printers, and computers on the curb side all the time. Even radios, stereos, and tv’s are in the stacks of stiff. Why not donate them to a school or an aspiring science student. They can use the parts to make the next discovery. What is really interesting you can take an old computer and put it back to work. So what if it does not run the latest software or can not be upgraded. If it still works, the computer can be repurposed for other uses.

People pay so much for specialty devices such as a device to turn on and turn off lights. an old computer would do the job just fine. The computer could be left in the attick without a monitor and work just fine. I took an old XT computer wirh just a floppy and made a sort of burgler alarm system for my apartment. with a battery backup which I already had, it was perect for me and i did not have to pay several hundred dollars for a device to do the same thing.

Last time I talked about how a to do list could be compiled for a computer to use. This is what I did with a short basic language program. The compiled program was so small it would fit on a floppy disk that the computer could automatically load and run. No hard drive was needed! I was able to put another piece of equipment back to work and save a landfill or at least part of one. Learning how to use to do lists to control a computer can save you money. Even if you feel that creating computer code might be a challenge, you get always get someone to help you. just create a to do list and have a programmer turn in into a computer program.

You will need some other parts such as joystick adapter, wire, and a open door detector that you can get at any good electronic store. Please let me know if you want more details. One neat thing about this program was I was able to incorporate two things. First was using speech synthesis to warn of an intruder. And secondly employ a modem (computer telephone device) to call me at a specific phone number and issue special tones so that I would know there was an intrusion. Almost state of the art technology using junk. Repurposing old equipment for new uses is a good goal to strive for. Here is the code I used for my burglar alarm system:

REM ***************************************************************
REM * program: doorchek.bas
REM * purpose check value of joystick port connected to door
REM * last update 02/04/1994
REM * 1994 - 2009 Hedonistic Systems
REM * Creative commons.
REM *
REM ---------------------------------------------------------------
REM mainline
REM
GOSUB housekeeping
WHILE TRUE%
GOSUB dothedoor
WEND
GOSUB endofjob
END
REM ---------------------------------------------------------------
REM housekeeping
housekeeping:
REM ........................................
REM basic variables and flag settings
OLDFLAG = 0
REM screentype% = 1 is 40 columns and 0 is 80 columns.
screentype% = 0
startflag = 0
TRUE% = -1
q$ = CHR$(34)
KEY OFF
SCREEN screentype%
CLS
REM .........................................
REM Give time before alarm system is set to enabled
REM so you can exit the premise without it going off.
FOR click = 1 TO 5000
NEXT click
REM .........................................
REM header
PRINT
title$ = "   Door switch recording system"
center = (W - LEN(title$)) / 2
PRINT TAB(center); title$
REM ..........................................
REM set datafile name to date and time
nowdate$ = LEFT$(DATE$, 2) + MID$(DATE$, 4, 2) + RIGHT$(DATE$, 2)
nowtime$ = LEFT$(TIME$, 2) + "." + MID$(TIME$, 4, 2)
nameoffile$ = nowdate$ + nowtime$
REM ...........................................
REM record starting time in file and on screen
fileaccess$ = "O"
doordid$ = "S"
GOSUB dofile
PRINT
PRINT "  Started at: "; TIME$; " on "; DATE$; "."
REM ............................................
REM set further file writing to append
fileaccess$ = "A"
REM ............................................
REM hold header and start time on screen
VIEW PRINT 6 TO 24
RETURN
REM ---------------------------------------------------------------
REM do the door
REM
dothedoor:
GOSUB getdoordata
GOSUB reportdoordata
GOSUB checkdearm
RETURN
REM ---------------------------------------------------------------
REM check to system if de-armed
checkdearm:
IF STRIG(3) THEN TRUE% = 0
RETURN
REM ---------------------------------------------------------------
REM end of job
REM
endofjob:
doordid$ = "E"
GOSUB dofile
PRINT
PRINT " System down at: "; TIME$; " on "; DATE$; "."
VIEW PRINT
RETURN
REM ---------------------------------------------------------------
REM get data from door
REM
getdoordata:
r = STRIG(1)
SELECT CASE r
        CASE -1
                flag = 1
        CASE 0
                flag = 2
        CASE ELSE
                GOSUB errornotice
END SELECT
RETURN
REM ---------------------------------------------------------------
REM report data from door
REM
reportdoordata:
SELECT CASE flag
        CASE OLDFLAG
                RETURN
        CASE 1
                GOSUB doorclosed
        CASE 2
                GOSUB dooropened
        CASE ELSE
                GOSUB errornotice
END SELECT
OLDFLAG = flag
RETURN
REM ---------------------------------------------------------------
REM door closed
REM
doorclosed:
IF startflag = 0 THEN
        startflag = 1
ELSE
        doordid$ = "C"
        GOSUB dofile
        PRINT " Door closed at: "; TIME$; " on "; DATE$; "."
END IF
RETURN
REM ---------------------------------------------------------------
REM door opened
REM
dooropened:
doordid$ = "O"
GOSUB dofile
PRINT " Door opened at: "; TIME$; " on "; DATE$; "."
GOSUB doalarm
RETURN
REM --------------------------------------------------------------
REM sound alarm
doalarm:
GOSUB domusic
REM gosub domodem
REM gosub dotalk
RETURN
REM --------------------------------------------------------------
REM play music  (make up your own tune if you wish.)
REM
domusic:
PLAY "mbcdeccdecdeffdeffgagfecgagfecc<b>cc"
RETURN
REM ---------------------------------------------------------------
REM do the modem thing
REM
domodem:
OPEN "com1:1200,n,8,1" FOR RANDOM AS #2
PRINT #2, "ATDT1234567;"
FOR clickon = 1 TO 10000: NEXT clickon
PRINT #2, "DT121212121212121212121212121212121212121212121212121212121"
FOR clickoff = 1 TO 10000: NEXT clickoff
CLOSE #2
RETURN
REM ------------------------------------------------------------------
REM do the file thing
REM
dofile:
OPEN fileaccess$, #1, nameoffile$
PRINT #1, q$; doordid$; q$; ","; q$; TIME$; q$; ","; q$; DATE$; q$
CLOSE #1
RETURN
REM ------------------------------------------------------------------
REM error notice
REM
errornotice:
VIEW PRINT
CLS
PRINT
PRINT
PRINT "  Error occurred, Warn supervisor NOW!"
RETURN
REM ------------------------------------------------------------------
REM * program: doorchek.bas
REM * purpose check value of joystick port connected to door
REM * last update 02/04/1994
REM * 1994-2009 Hedonistic Systems
REM * Creative Commons
REM *
REM *******************************************************************
REM -------------------------------------------------------------
REM TALK MESSAGE  (requires external program!)
REM
dotalkthing:
FOR Xit = 1 TO 3
talkmessage:
SHELL "say W-AH-R-N-IH-N-G, tz-eh-r ih-s ah-n IH-N-T-R-UH-D-R"
NEXT Xit
RETURN
Advertisements